hspice - Power Plane Inductance
Let us take a look at another application of a 2D field solver. Here we will try to calculate the inductance of a power plane. Traditional method of calculation of power plane inductance involves the calculation of the capacitance per unit length followed by calculation of the impedance Zo. The inductance is then calculated using the formula.L = Zo2C
A 2D field solver can readily give out the value of the inductance per unit length and from that we can get the value of inductance per square. Note that inductance per square cm is same as inductance per square inches or inductance per square meter. If you double the length, the inductance doubles. If you double the width, inductance is halved. So for a square the inductance remains the same, no matter what is the value of the side of a square. So we do not say inductance per square cm or inductance per square inch, we just say inductance per square. At least here, we forget the difference in mils, cm and inches – keeps life easier !!!
Here is the Hspice code that gives you the inductance of a 400 mils wide ( this is about 1 cm) trace places 3 mils above the ground. The trace height of the signal has been assumed to be 0.685 mils corresponding to ½ oz Cu. The relative dielectric constant has been assumed to be 4.3, although it affects the capacitance per unit length not the inductance per unit length.
* W element, Inductance calculation for power plane
* XXXXXX
* ------------------------------------ Z = 4mils
* Er = 4.3 H = 3mils
* ------------------------------------ Z = 1mils
* //// Bottom Ground Plane ///////////
* ------------------------------------ Z = 0
W1 in1 0 out1 0 FSmodel=demo N=1 l=0.97
* Materials
.MATERIAL copper METAL CONDUCTIVITY=5.76e+07
.MATERIAL diel_1 DIELECTRIC ER = 4.3 LOSSTANGENT=1.2e-3 CONDUCTIVITY=8.2e-4
* Conductor crossection shapes
.SHAPE rect RECTANGLE WIDTH = 400mils HEIGHT = 0.685mils
* Dielectric stack-up
.LAYERSTACK Stack
+ LAYER = (copper, 1mils)
+ LAYER = (diel_1 3mils)
* Field-solver options
.FSOPTIONS myOption ACCURACY = HIGH GRIDFACTOR = 1
+ ComputeRo=no ComputeRs=no ComputeGo=no ComputeGd=no PRINTDATA=YES
.MODEL demo W ModelType=FieldSolver
+ LAYERSTACK=Stack FSOptions=myOption
+ RLGCFILE= rlgc.txt
+ CONDUCTOR = ( MATERIAL=copper, SHAPE=rect, ORIGIN=(1000mils, 4mils) )
*Analysis
.tran 0.1ns 100ns
.option post
.end
If we run the above hspice field solver code, we get the following result.
*SYSTEM_NAME : demo
*
* Half Space, AIR
* ------------------------------------ Z = 1.016000e-004
* diel_1 H = 7.620000e-005
* ------------------------------------ Z = 2.540000e-005
* //// Bottom Ground Plane ///////////
* ------------------------------------ Z = 0
* L(H/m), C(F/m), Ro(Ohm/m), Go(S/m), Rs(Ohm/(m*sqrt(Hz)), Gd(S/(m*Hz))
.MODEL demo W MODELTYPE=RLGC, N=1
+ Lo = 9.134582e-009
+ Co = 5.119388e-009
The inductance per meter length is 9.13x10-9 Henry for 1 cm wide trace spaced 3 mils above ground. For 1 cm length of trace this will correspond to 91.3 pH. We can say that the inductance of a 1 cm x 1cm trace spaced 3 cm above ground is 91.3 pH. We therefore can say that the inductance per square is 91.3 pH for power trace spaced 3 mils above ground.
If we run the above code for 6 mils separation between power and ground plane, the code looks as follows.
* W element, Inductance calculation for power plane
* XXXXXX
* ------------------------------------ Z = 7mils
* Er = 4.3 H = 6mils
* ------------------------------------ Z = 1mils
* //// Bottom Ground Plane ///////////
* ------------------------------------ Z = 0
W1 in1 0 out1 0 FSmodel=demo N=1 l=0.97
* Materials
.MATERIAL copper METAL CONDUCTIVITY=5.76e+07
.MATERIAL diel_1 DIELECTRIC ER = 4.3 LOSSTANGENT=1.2e-3 CONDUCTIVITY=8.2e-4
* Conductor crossection shapes
.SHAPE rect RECTANGLE WIDTH = 400mils HEIGHT = 0.685mils
* Dielectric stack-up
.LAYERSTACK Stack
+ LAYER = (copper, 1mils)
+ LAYER = (diel_1 6mils)
* Field-solver options
.FSOPTIONS myOption ACCURACY = HIGH GRIDFACTOR = 1
+ ComputeRo=no ComputeRs=no ComputeGo=no ComputeGd=no PRINTDATA=YES
.MODEL demo W ModelType=FieldSolver
+ LAYERSTACK=Stack FSOptions=myOption
+ RLGCFILE= rlgc.txt
+ CONDUCTOR = ( MATERIAL=copper, SHAPE=rect, ORIGIN=(1000mils, 7mils) )
*Analysis
.tran 0.1ns 100ns
.option post
.end
This gives the result as follws.
*SYSTEM_NAME : demo
*
* Half Space, AIR
* ------------------------------------ Z = 1.778000e-004
* diel_1 H = 1.524000e-004
* ------------------------------------ Z = 2.540000e-005
* //// Bottom Ground Plane ///////////
* ------------------------------------ Z = 0
* L(H/m), C(F/m), Ro(Ohm/m), Go(S/m), Rs(Ohm/(m*sqrt(Hz)), Gd(S/(m*Hz))
.MODEL demo W MODELTYPE=RLGC, N=1
+ Lo = 1.779617e-008
+ Co = 2.587003e-009
The inductance value is now 1.78x10-8 Henry per meter. This corresponds to 178 pH per square. The inductance value therefore, doubles by doubling the space between the power and ground plane. Engineers simplify this by expressing that the inductance per square is 30 pH per mil of spacing between the power and ground plane. A power and ground plane separated 10 mils away will roughly have per square inductance of 300 pH.
Previous Next