hspice - Inductance of a trace – an interesting rule of thumb

If the line width is equal to the spacing from the ground plane, then the total inductance of a PCB trace is close to 10 nH/inch. This makes for a simple, easy to remember rule of thumb.

If a 4 mils trace is spaced 4 mils from ground trace, then the inductance of 1 inch trace is 1 nH. The inductance of 0.5 inch trace is 5 nH – that is easy to remember.

Let us try to verify this statement using Hspice 2D field solver. Here is the code to generate and rlgc matrix for a 4 mils trace spaced 4 mils above the ground plane.

* W element, Inductance calculation for H=W

*                  XXXXXX     
*  ------------------------------------ Z = 5mils
*       Er = 4.3   H = 4mils
*  ------------------------------------ Z = 1mils
*  //// Bottom Ground Plane ///////////
*  ------------------------------------ Z = 0

W1 in1   0 out1   0 FSmodel=demo N=1 l=0.97

* Materials
.MATERIAL copper METAL CONDUCTIVITY=5.76e+07
.MATERIAL diel_1 DIELECTRIC ER = 4.3  LOSSTANGENT=1.2e-3 CONDUCTIVITY=8.2e-4

* Conductor crossection shapes
.SHAPE rect RECTANGLE WIDTH = 4mils HEIGHT = 1mils

* Dielectric stack-up
.LAYERSTACK Stack 
+ LAYER = (copper, 1mils) 
+ LAYER = (diel_1 4mils) 

* Field-solver options
.FSOPTIONS myOption ACCURACY = HIGH GRIDFACTOR = 1 
+ ComputeRo=No ComputeRs=No ComputeGo=No ComputeGd=No PRINTDATA=YES

.MODEL demo W ModelType=FieldSolver 
+ LAYERSTACK=Stack FSOptions=myOption
+ RLGCFILE= rlgc.txt
+ CONDUCTOR = ( MATERIAL=copper, SHAPE=rect, ORIGIN=(1000mils, 5mils) )

*Analysis
.tran 0.1ns 100ns
.option post
.end

If you simulate the above code you will get the following result.

*SYSTEM_NAME : demo
*
*       Half Space, AIR
*  ------------------------------------ Z = 1.270000e-004
*       diel_1   H = 1.016000e-004
*  ------------------------------------ Z = 2.540000e-005
*  //// Bottom Ground Plane ///////////
*  ------------------------------------ Z = 0

* L(H/m), C(F/m), Ro(Ohm/m), Go(S/m), Rs(Ohm/(m*sqrt(Hz)), Gd(S/(m*Hz))

.MODEL demo W MODELTYPE=RLGC, N=1
+ Lo = 3.740041e-007
+ Co = 8.615520e-011

The inductance per unit length for the structure with 4 mils trace with 4 mils separation above ground plane is 3.74x10-7 henry per meter. This is equivalent to 9.50 nH per inch. Of course, we have assumed the trace thickness of the copper to be 1 mils for convenience. The 1 oz Cu is equivalent to 1.37 mils, so 1 mil is a realistic figure. If you want to simulate the same structure with 1 oz or 1.37 mils trace thickness you just need to change the .SHAPE statement as follows.

.SHAPE rect RECTANGLE WIDTH = 4mils HEIGHT = 1.37mils

This gives an inductance of 9.23 nH per inch. This was expected. A thicker trace will have lower inductance per unit length. Reducing the trace thickness to 0.5 oz or 0.685 mils increases the inductance 9.77 nH per inch. The rule of thumb approximation is slightly higher than the actual value for 4 mils trace and a useful, easy to remember figure.

If we increase the trace width to 10 mils and the separation between the ground and the trace to 10 mils it gives inductance value of 4.03x10-7 henry per meter or 10.25 nH per inch for ½ oz Cu.




Previous                    Next