Differential Impedance Calculator Using HSPICE 2D Field Solver

Hspice can calculate the single ended and differential impedance. It actually generates an RLGC matrix. It generates a matrix that computes the coupled inductance per unit length and coupled capacitance per unit length. Let us jump start and take a look at the hspice code that will generate the rlgc matrix.

* W element, field-solver differential trace
*   10 mils    18 mils     10 mils
*  XXXXXXXXXX            XXXXXXXXXX    
*  ------------------------------------ Z = 8mils
*       Er = 4.3   H = 7mils
*  ------------------------------------ Z = 1mils
*  //// Bottom Ground Plane ///////////
*  ------------------------------------ Z = 0

W1 in1 in2  0 out1 out2   0 FSmodel=demo N=2 l=0.97

* Materials
.MATERIAL copper METAL CONDUCTIVITY=5.76e+07
.MATERIAL diel_1 DIELECTRIC ER = 4.5  LOSSTANGENT=1.2e-3 CONDUCTIVITY=8.2e-4

* Conductor crossection shapes
.SHAPE rect RECTANGLE WIDTH = 10mils HEIGHT = 1mils

* Dielectric stack-up
.LAYERSTACK Stack 
+ LAYER = (copper, 1mils) 
+ LAYER = (diel_1 7mils) 

* Field-solver options
.FSOPTIONS myOption ACCURACY = LOW GRIDFACTOR = 1 
+ ComputeRo=yes ComputeRs=yes ComputeGo=Yes ComputeGd=yes PRINTDATA=YES

.MODEL demo W ModelType=FieldSolver 
+ LAYERSTACK=Stack FSOptions=myOption
+ RLGCFILE= rlgc.txt
+ CONDUCTOR = ( MATERIAL=copper, SHAPE=rect, ORIGIN=(1000mils, 8mils) )
+ CONDUCTOR = ( MATERIAL=copper, SHAPE=rect, ORIGIN=(1018mils, 8mils) )
*Analysis
.tran 0.1ns 100ns
.option post
.end

The differential traces are 10 mils wide and spaced 18 mils apart. The dielectric has height of 7 mils with Er of 4.5. If we simulate the above code, it generate an rlgc.txt file with the following content.

For now we will concentrate only on the values of Lo and Co.

+ Lo = 3.328263e-007
+          5.994802e-008 3.328263e-007
+ Co = 1.055310e-010
+         -8.672713e-012 1.055310e-010

In the above equation, if we define,

L11 = 3.328263e-007
L12 = 5.994802e-008

C11 =  1.055310e-010
C12 =  8.672713e-012

Then the differential impedance is given by

Zdiff = [(L11 - L12 )/ (C11 + C12 )] ½  
         =  97.8 Ohms

Previous - Routing Differential Signals in PADS                                Chapter 8 - Question and Anaswer